GAMBAS BOOK 3.19.5

The FileView (gb.form) control displays files in a selected directory.

A FileView control can be created:

Dim hFileView As FileView

hFileView = New FileView ( Parent As Container ) As "EventName"

The FileView class has these properties:

Table 6.9.4.1.1 : Properties of the FileView class.

Notes:

• Access to the file name for a selected file - mode Single - in the project is obtained if you store the value of the property FileView.Current for example in a (public) variable sFileName = FileView.Current. You can access the files selected in FileView.Multiple = True mode, for example, if you save the list of selected file names, stored in the FileView.Selection property, in a (public) variable of the type string array such as aFileNames = FileView.Selection.
• This is an example of a file filter: FileView1.Filter = [“*.txt”, “*.png”, “*.pd*”, “*.jp*”, “*.xml”] .
• The filter should be followed in the source code by the instruction Wait, so that the file count is updated immediately.

Figure 6.9.4.1.1: Selected file in a FileView

Figure 6.9.4.1.2: List of selected files in a FileView

The FileView class has these selected methods:

Table 6.9.4.2.1 : Selected methods of the FileView class

The FileView class has the following events, among others:

Table 6.9.4.3.1 : Events of the FileView class

The source code for the project implements the above notes:

' Gambas class file
 
Public sFileName As String
Public aFileNames As String[]
 
Public Sub Form_Open()
 
  FMain.Resizable = False
  DirBox1.Value = "/home/hans/BildTon" ' (Start-)Folder
 
  FileView1.Dir = DirBox1.Value
  FileView1.IconSize = 32 ' Default-Value = 32
  FileView1.ShowPreview = True
  FileView1.ShowHidden = True
  FileView1.Background = &HC3DDFF
  FileView1.Foreground = Color.DarkGreen
  FileView1.Mode = Select.Single
 
  FileView1.Filter = ["*.txt", "*.png", "*.pd*", "*.jp*", "*.xml"]
  Wait
 
  btnShowFileListContent.Enabled = False
 
End
 
Public Sub FileView1_Click()
 
  Dim sFileDir, sFilePath As String
 
  sFileName = FileView1.Current
  sFileDir = FileView1.Dir
  sFilePath = sFileDir &/ sFileName
 
  lblFileName.Text = Subst("&1 &2 &3", ("Filename"), ":", sFileName)
 
End
 
Public Sub FileView1_Select()
  If FileView1.Current Then
     Print Subst("&1 '&2' &3", ("The file"), FileView1.Current, ("has been selected."))
  Endif
End
 
Public Sub DirBox1_Click()
  FileView1.Dir = DirBox1.Value
End
 
Public Sub btnSetMultiple_Click()
 
  If FileView1.Mode = Select.Single Then ' The default-value is "Single"
     FileView1.Mode = Select.Multiple
     btnSetMultiple.Caption = "Set file selection to single"
     btnShowFileListContent.Enabled = True
  Else
     FileView1.Mode = Select.Single
     btnSetMultiple.Caption = "Set file selection to multiple"
     btnShowFileListContent.Enabled = False
  Endif
 
End
 
Public Sub btnShowFileListContent_Click()
 
  Dim sFile, sContent As String
 
  If FileView1.Mode = Select.Multiple Then
     If FileView1.Selection.Count > 0 Then
        lblFileName.Text = ""
        aFileNames = FileView1.Selection
        For Each sFile In aFileNames
          sContent &= sFile & gb.Lf
        Next
        Message.Info("Selected files:<hr>" & sContent)
        FileView1.UnselectAll()
        FileView1.Mode = Select.Single
        btnSetMultiple.Caption = "Set file selection to multiple"
        btnShowFileListContent.Enabled = False
     Endif
  Endif
End