GAMBAS-BUCH 3.19.5

Eine DataSource ist ein Container-Steuerelement, das allen Steuerelementen in diesem Container Daten aus einer Datenbank (rekursiv) zur Verfügung stellt. Die Datenbank wird über die Connection-Eigenschaft festgelegt.

Welche DB-Daten tatsächlich – zum Beispiel zur Anzeige – zur Verfügung stehen sollen, können Sie über die Eigenschaften Table und Filter festlegen:

  DataSource1.Connection = DBCS.DBConnection
'---   Filtering   --------------------------------------------------------------
  DataSource1.Table = "contacts"
  DataSource1.Filter = "id > 4 AND wohnort <> 'Berlin' AND wohnort NOT LIKE 'G%'"
'--------------------------------------------------------------------------------
  DataSource1.Sort = "wohnort"

22.5.3.1 Eigenschaften

Die Klasse DataSource verfügt über die folgenden Eigenschaften:

Tabelle 22.5.3.1.1 : Eigenschaften der Klasse DataSource

Die Klasse DataSource verfügt über diese speziellen Methoden:

Tabelle 22.5.3.2.1 : Methoden der Klasse DataSource

Die Klasse DataSource hat nur drei spezielle Ereignisse.

• BeforeSave ( Data As Result ): Dieses Ereignis wird ausgelöst, bevor die Werte von den verwendeten DataControls in die DB-Tabelle gespeichert werden, sofern eine Verbindung zu ihr besteht. Die Daten sind im Ergebnis-Objekt (Daten-Typ Result) gespeichert. Verwenden Sie das Ereignis, um Daten zu ändern, bevor diese in die Datenbank-Tabelle geschrieben werden.
• BeforeDelete ( Keys As Variant[] ): Dieses Ereignis wird ausgelöst, bevor ein Datensatz gelöscht wird. Keys ist ein Array mit den Werten des Primärschlüssels, der den zu löschenden Datensatz identifiziert. Sie können das Löschen abbrechen, indem Sie das Ereignis stoppen.
• Change ( ): Das Ereignis wird ausgelöst, wenn der aktuelle Datensatz geändert wurde und alle Steuerelemente im Container aktualisiert worden sind.

Beispiel 1 – Ereignis: BeforeSave ( Data As Result )

Der ausgewählte Datensatz kann vor dem Speichern noch geändert werden. Die hier angegebenen zwei potentiellen Änderungen sollen nur die Vorgehensweise demonstrieren:

Public Sub DataSource1_BeforeSave(Data As Result)
 
'-- If the date is missing, the current date is saved.
    If Data["date"] = Null Then Data["date"] = Now()
 
'-- If the image is missing, you will be prompted to save an image.
    If Data["picture"].Length = 0 Then 
       Message.Info("Action:<br>Insert new image.")
    Else
       If Message.Question("Do you want to change the current image?", "Yes", "No") = 1 Then
          Print "Action: Change current image."
       Else 
          Print "Action: No change current image."
          Stop Event
       Endif
    Endif
 
  Catch
    Message.Error(Error.Text & gb.NewLine & Error.Where)
 
End

Beispiel 2 – Ereignis: BeforeDelete ( Keys As Variant[ ] )

Im Vordergrund steht hier die Sicherheitsabfrage, ob der ausgewählte Datensatz tatsächlich gelöscht werden soll:

Public Sub DataSource1_BeforeDelete(Keys As Variant[])
 
  Dim vElement As Variant
  Dim sQuestion As String
' For Each vElement In Keys
'   Print vElement
' Next
  sQuestion = Subst("&1 `&2` &3", ("Should the record with the ID"), Keys[0], ("be deleted?"))  
  If Message.Question(sQuestion, "Yes", "No") = 2 Then
     Stop Event
  Endif  
End

Beispiel 3 – Löschen des aktuellen Datensatzes aus der DB-Tabelle:

Dim bFlag As Boolean
If DataSource1.Remove() = False Then Print "DAS LÖSCHEN DES DATENSATZES WAR ERFOLGREICH!"

Beispiel 4 – Setzen des DB-Tabellen-Feldes, nach dem sortiert werden soll:

DataSource1.Sort = "PLZ"

Beispiel 5 – Setzen eines Filters:

  MDataBase.ConnectDB("mysql", "localhost", "3606", "root", "sql", "Kontakte", "kontakte")
  DataSource1.Connection = MDataBase.hConnection
  DataSource1.Table = "kontakte"
' DataSource1.Filter = "Wohnort <> 'Leipzig' AND Wohnort NOT LIKE 'G%'" ' "Wohnort <> \"Leipzig\""
  DataSource1.Filter = "" ' Standard-Filter

Hinweis: In MySQL sind die Muster standardmäßig nicht von der Groß/Kleinschreibung abhängig.

Ergänzungen

In commit https://gitlab.com/gambas/gambas/commit/6902893dd50e6480a63aa2268207241aea021f3 wurde die neue Eigenschaft „IgnoreParent“ im DataSource-Steuerelement hinzugefügt. Wenn diese Eigenschaft auf TRUE gesetzt ist, so filtert die DataSource ihren Inhalt nicht mit den Primärschlüsseln ihrer übergeordneten DataSources. Es wird sich so verhalten, als wäre es eine Root-DataSource.