GAMBAS-BUCH 3.19.3

Das Steuerelement ToolPanel implementiert eine Toolbox mit mehreren vertikal scrollbaren Toolbar-Bars. Die Klasse ist erzeugbar. So erzeugen Sie ein neues ToolPanel:

Dim hToolPanel As ToolPanel
hToolPanel = New ToolPanel ( Parent As Container ) [ As "EventName" ]

Die Klasse verhält sich wie ein Nur-Lesen-Array und gibt ein Objekt zurück, das eine der Toolboxen repräsentiert.

Dim hToolPanel As ToolPanel
Dim hToolPanelContainer As _ToolPanelContainer
hToolPanelContainer = hToolPanel [ Index As Integer ]

Die Klasse ToolPanel verfügt u.a. über diese Eigenschaften:

Tabelle 18.4.1.1 : Eigenschaften der Klasse ToolPanel

Die Klasse ToolPanel verfügt nur über zwei relevante Ereignisse:

Tabelle 18.4.2.1 : Ereignisse der Klasse ToolPanel

Vorgestellt wird Ihnen ein kleines Projekt, bei dem Sie in einem ToolPanel eine von drei Toolbars auswählen können, die unterschiedliche Funktionalitäten bereitstellen:

Abbildung 18.4.3.1: Auswahl: Farbe

Abbildung 18.4.3.2: Auswahl: Datum

Abbildung 18.4.3.3: Auswahl: Datei

Für das ToolPanel können Sie einerseits dessen grundlegende Eigenschaften in der IDE festlegen und andererseits nach der Festlegung, wie viele Toolbars das ToolPanel aufnehmen soll, auch die wesentlichen Eigenschaften der einzelnen ToolBars.

Der Quelltext sieht sehr übersichtlich aus, weil nur noch die wesentliche Funktionalität der einzelnen Toolbars festzulegen ist (Auswahl Farbe, Auswahl Datum1 und Datum2 sowie Auswahl Datei):

' Gambas class file
 
Public Sub Form_Open()
 
    FMain.Resizable = False
    ColorChooser1.Value = &HCF3FFF
 
    FileChooser1.Root = User.Home
    FileChooser1.Multi = False
    FileChooser1.Filter = ["*.png;*.jp*;*.gif", "Picture files", "*.txt;*.xml;*.conf", "Text files"]
    FileChooser1.FilterIndex = 0        '-- Display images with the extensions png, jp* and gif first
'-- FileChooser1.FilterIndex = -1       '-- Display all files
'-- FileChooser1.ShowFile = True        '-- Default-Value is 'True'
'-- FileChooser1.ShowDirectory = False  '-- Default-Value is 'False'
'-- FileChooser1.ShowButton = False     '-- Default-Value is 'False'
    FileChooser1.ShowPreview = True     '-- Default-Value is 'False'
End
 
Public Sub DateChooser1_Change()
 
  lblDifferenceInDays.Text = RunDateDiff(DateChooser1.Value, DateChooser2.Value)
 
End
 
Public Sub DateChooser2_Change()
 
  lblDifferenceInDays.Text = RunDateDiff(DateChooser1.Value, DateChooser2.Value)
 
End
 
Private Sub RunDateDiff(hDate1 As Date, hDate2 As Date) As Integer
 
  Return Abs(DateDiff(hDate1, hDate2, gb.Day)) + 1
 
End
 
Public Sub ColorChooser1_Change()
 
  lblColor.Text = "&H" & Hex(ColorChooser1.Value)
 
End
 
Public Sub FileChooser1_Change()
 
    lblFilename.Text = ""
    If FileChooser1.SelectedPath Then lblFilename.Text = FileChooser1.SelectedPath
 
End
 
Public Sub FileChooser1_Activate()
 
    If FileChooser1.Multi = False Then
       lblFilename.Text = FileChooser1.SelectedPath
   '-- Message.Info("Selected file:<hr>" & FileChooser1.SelectedPath)
   '-- Desktop.Open(FileChooser1.DirView.Current &/ FileChooser1.FileView.Selection[0])
       Desktop.Open(FileChooser1.SelectedPath)
    Endif
 
End

Eine Besonderheit besteht bei der Auswahl einer Datei darin, dass nach einem Doppel-Klick auf eine Datei die ausgewählte Datei mit dem (Standard-)Editor geöffnet und deren Inhalt angezeigt wird.

Ihnen wird der komplette Quelltext in einem Projekt-Archiv im Download-Bereich zur Verfügung gestellt.