GAMBAS BOOK 3.19.1

This class provides an HTTP client that sends requests to an HTTP server and receives its response.

To create a new HTTP client:

Dim hHTTPClient As HTTPClient
hHTTPClient = New HTTPClient() As "hHTTPClient"  ' → Ereignisname (optional)

The HTTPClient class has these properties:

Table 24.2.4.0.1 : Properties of the HTTPClient class

The HTTPClient class has the static method DownLoad(…):

Static Function Download ( URL As String [ , Headers As String[] ] ) As String

- URL ist die Adresse
- Headers ist ein optionales String-Array der verwendeten Header

The HTTPClient class has these selected methods:

Table 24.2.4.0.2 : Methods of the HTTPClient class

Notes * * Post ( ContentType As String, Data As String [ , Headers As String[], TargetFile As String ] ):

• ContentType is the MIME type of the data. Data is the data to be set. Headers is an optional string array of HTTP headers. TargetFile is an optional file to which the response will be written. If TargetFile is not specified, the data received from the server is stored in memory. You can access the data using the standard stream methods or the peek method on the document. If TargetFile is specified, the data received from the server is stored in the specified file and is not available in the internal memory buffer. If you want to transmit form data, use 'application/x-www-form-urlencoded' as the ContentType header of the request. Then format the 'Data' parameter with a string using the following syntax: Key1=Value1&Key2=Value2&… .
• Get ( [ Headers As String[], TargetFile As String ] ):
• Header is an optional string array of HTTP headers sent with the request to the server. TargetFile is an optional file to which the response is written. If TargetFile is not specified, the data received from the server is stored in memory. You can access the data using standard stream methods or the Peek method. If TargetFile is specified, the data received from the server is stored in the specified file and is not available in the internal memory buffer afterwards.
• Put ( ContentType As String, Data As String [ , Headers As String[ ], TargetFile As String ] ):
• ContentType is the MIME type of the data. Data is the data to be set. Headers is an optional string array of HTTP headers. TargetFile is the path of an optional file to which the response will be written.
• PostFile ( ContentType As String, Path As String [ , Headers As String[ ], TargetFile As String ] ):

• ContentType is the MIME type of the file. Path is the path of the file to be sent. Headers is an optional string array of HTTP headers. TargetFile is an optional file to which the response will be written. If TargetFile is not specified, the data received from the server is stored in memory. You can access it using standard stream methods or the Peek method. However, if TargetFile is specified, the data received from the server is stored in the specified file and is not available in the internal memory buffer afterwards.

The HTTPClient class has these events:

Table 24.2.4.0.3 : Events of the HTTPClient class

In the example, the Get() method is used without parameters. Therefore, the data received from the HTTP server is stored in memory. This data is accessed with standard stream methods. The website data is manageably small and is displayed in a text box:

Figure 24.2.4.0.1: Output of the external IP address.

This is the complete source code:

[1] ' Gambas class file
[2]
[3] Public Sub Form_Open()
[4]
[5]     MAdditional.CheckNetwork()
[6]     FMain.Caption = ("Current external IP address")
[7]
[8] '-- Note the text on this web page: https://ipecho.net/developers.html
[9]     lblIPAdress.Text = HTTPGetIP("https://ipecho.net/plain")
[10]
[11] End
[12]
[13] Public Function HTTPGetIP(argURL As String) As String
[14]
[15]     Dim hHTTPClient As HttpClient
[16]     Dim sResult As String
[17]
[18]     hHTTPClient = New HttpClient
[19]     hHTTPClient.URL = argURL
[20]     hHTTPClient.Async = False
[21]     hHTTPClient.TimeOut = 10
[22]
[23]     hHTTPClient.Get()
[24]
[25]     If Lof(hHTTPClient) Then sResult = Read #hHTTPClient, Lof(hHTTPClient)
[26]
[27]     Return sResult
[28]
[29] End

Comment:

• In line 5, the procedure CheckNetwork is used to test whether a network is reachable.
• The external IP address is displayed in line 9 as the value of the function HTTPGetIP(…).
• First, a new HTTPClient is created in line 18 in the HTTPGetIP(…) function.
• The client is then assigned essential properties. The URL of the page to be called up is passed as an argument to the above-mentioned function in line 19.
• Afterwards, the Async property is set to False, which results in the setting of a timeout → TimeOut property in Table 24.2.4.0.1.
• Then the data in line 23 is retrieved with the Get() method and stored in memory.
• Finally, in line 25, the memory is completely read and stored in the function value by the HTTPGetIP(…) function, which is output in line 27.

The project uses the module MAdditional, which contains this procedure, among others:

Public Sub CheckNetwork()
 
    Dim sResponse, sCommand As String
    Dim sIPAddress As String
 
'-- With Desktop.NetworkAvailable (gb.desktop) you can determine whether a network connection exists.
    If Not Desktop.NetworkAvailable Then
       Message.Error(("No network available!<hr>The application will be terminated."))
       Quit
    Endif
 
'-- Check connection to local router by trying to obtain the IP address of the gateway
    sCommand = "route -n | grep ^0.0.0.0 | awk '{print $2}'"
    Shell sCommand To sIPAddress
    If Not sIPAddress Then
       Message.Error(("No connection to lokal router!<hr>The application will be terminated."))
       Quit
    Endif
 
    sCommand = "ping -c 1 8.8.8.8"
    Shell sCommand To sResponse
    If Not InStr(sResponse, "8.8.8.8 ping") Then
       Message.Error(("No connection to the Internet!<hr>The application will be terminated."))
       Quit
    Endif
 
End