This control implements a document viewer.

The class can be created. To create a new DocumentView object:

  Dim hDocumentView As DocumentView
  hDocumentView = New DocumentView ( Parent As Container ) [ As "EventName" ]

The DocumentView class has these properties

Table 23.13.1.1 : Properties of the DocumentView class

The DocumentView class has these essential methods:

Table 23.13.2.1 : Methods of the DocumentView class

The DocumentView class has these events:

Table 23.13.3.1 : Events of the DocumentView class

The developer of the control, Fabien Bodard, described the possible applications of a DocumentView as follows: 'It can display not only PDF documents, but actually anything you want, as long as there is a utility that allows you to render the content. DocumentView provides you with 'canvases' on which you can draw whatever you want. So it can be anything as long as you can draw it with the Paint.DrawImage() function.

A typical application for the DocumentView control is the display of PDF files:

Figure 23.13.3.2.1: Display of a PDF document (excerpt)

Source code:

' Gambas class file
 
Private $PDF_Document As New PdfDocument
 
Public Sub Form_Open()
    btnOpen.SetFocus()
End
 
Public Sub btnOpen_Click()
  Dialog.Filter = ["*.pdf", "PDF-Files"]
  If Not Dialog.OpenFile() Then
     $PDF_Document.Open(Dialog.Path)
 '-- Setup the number of pages shown in the viewer. It enforce the layout event call
     DocumentView1.Count = $PDF_Document.Count
     DocumentView1.Refresh()
     Wait
  Else
     Return
  Endif
End
 
Public Sub DocumentView1_Layout(Page As Integer)
  DocumentView1.Layout.Width = $PDF_Document[Page + 1].Width
  DocumentView1.Layout.Height = $PDF_Document[Page + 1].Height
End
 
Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
'-- Draw the pdf image
    Paint.DrawImage($PDF_Document[Page + 1].Image, 0, 0, Paint.Width, Paint.Height)
End
 
Public Sub DocumentView1_Zoom()
    $PDF_Document.Zoom = Last.Zoom
End
 
Public Sub Form_Resize()
    DocumentView1.Column = 1
    DocumentView1.Refresh()
    Wait
End
 
Public Sub btnClose_Click()
    FMain.Close()
End

In the second project, each image content is drawn on a separate image - as a canvas - and displayed in the size specified by the slider in the range from 0% to 200% for each individual page:

Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
    Paint.DrawImage($aImages[Page], 0, 0, Width, Height)
End

The focus is not on the detailed preview of individual images, but on the overview of all images in the selected directory:

Figure 23.13.3.3.1: Reduced display of images in a DocumentView

Source code:

' Gambas class file
 
Private $sPath As String
Private $aImages As New Image[]
 
Public Sub Form_Open()
 
    lblMin.Text = sliderZoom.MinValue
    lblMax.Text = Str(sliderZoom.MaxValue) & "%"
 
    DocumentView1.Arrangement = Arrange.None
    DocumentView1.Columns = 0
    DocumentView1.Center = True
    DocumentView1.Spacing = 20
 
    sliderZoom.Value = 30
    DirBox1.Tooltip = "Select an image directory!"
    ChangePath()
 
End
 
Public Sub DirBox1_Change()
    $sPath = Last.Path
    ChangePath()
    sliderZoom.Value = 32
End
 
Public Sub ChangePath()
 
    Dim sFile As String
    Dim hImage As Image
 
    $aImages.Clear()
    For Each sFile In Dir($sPath, Null, gb.File)
        Select Case File.Ext(sFile)
          Case "png", "jpg"
            hImage = Image.Load($sPath &/ sFile)
            $aImages.Add(hImage)
        End Select
    Next
    DocumentView1.Count = $aImages.Count
End
 
Public Sub DocumentView1_Draw(Page As Integer, Width As Integer, Height As Integer)
    Paint.DrawImage($aImages[Page], 0, 0, Width, Height)
End
 
Public Sub DocumentView1_Layout(Page As Integer)
 
'-- Allow to define specific layout for items
'-- It is called before the drawing... so images need to be seen twice in this case
    DocumentView1.Layout.Width = $aImages[Page].W
    DocumentView1.Layout.Height = $aImages[Page].H
End
 
Public Sub DocumentView1_Zoom()
    DocumentView1.Refresh()
End
 
Public Sub sliderZoom_Change()
    DocumentView1.Zoom = sliderZoom.Value / 100
    lblMax.Text = Str(sliderZoom.Value) & "%"
End

You can find the project archives for the two projects presented in the download area.