Diese statische Klasse Color (gb.qt4) hat Eigenschaften, welche die System-Farben zurückgeben. Beachten Sie, dass in Gambas neben der Klasse Color (gb.qt4) auch eine Klasse Color (gb.image) existiert. Diese statische Klasse Color (gb.image) definiert Konstanten vordefinierter Farben und enthält einige nützliche Methoden, um mit Farben umzugehen. Es ist so, dass in Color (gb.image) die angesprochenen Farb-Konstanten und die nützlichen Methoden sind und in Color (gb.qt4) die Systemfarben. Die Klasse Color (gb.image) enthält Konstanten und Methoden, die nicht von bestimmten Bibliotheken abhängen. Die Konstanten liegen im RGB-Format vor. Die Methoden nutzen von Minisini geschriebene oder adaptierte Algorithmen. Die Systemfarben hingegen sind an das aktuelle System gebunden und werden vom aktuellen Toolkit bereitgestellt. Die Klasse Color (gb.qt4) muss also in der gb.qt4-Komponente enthalten sein, um auf diese Farbkonstanten zugreifen zu können.

Es werden diese (statischen) Eigenschaften in der folgenden Tabelle beschrieben → Background, ButtonBackground,  ButtonForeground, Foreground, LightBackground, LightForeground, SelectedBackground, SelectedForeground, TextBackground, TextForeground, TooltipBackground und TooltipForeground:

Tabelle 25.3.1.1.1: Farbkonstanten Klasse Color (gb.qt4)

Diese Klasse Color (gb.image) ist statisch und definiert diese Farb-Konstanten:

Tabelle 25.3.1: Farbkonstanten

Die zahlreichen Methoden der Klasse Color (gb.image) ermöglichen dem Benutzer eine qualifizierte Arbeit mit Farben in Gambas.

Tabelle 25.3.1.3.1: Methoden der Klasse Color (gb.image)

Es werden in den ausgewählten Beispielen die Originalfarben und die geänderten Farben in zwei ColorButton oder drei ColorChooser angezeigt sowie der verwendete Quelltext angegeben.

Beispiel 1 – Color.Darker(..)

Public Sub btnDarker_Click()
 
    Dim iSourceColor, iResultColor As Integer
 
    iSourceColor = ColorButton1.Color
    iResultColor = Color.Darker(iSourceColor)
    ColorButton2.Color = iResultColor
'-- ColorButton2.Color = Color.Darker(ColorButton1.Color) '-- Short version
 
End

Beispiel 2 – Color.Lighter(..)

Public Sub btnLighter_Click()
  ColorButton2.Color =  Color.Lighter(ColorButton1.Color)
End

Beispiel 3 – Color.Desaturate(..)

Public Sub btnDesaturate_Click()
  ColorButton2.Color =  Color.Desaturate(ColorButton1.Color)
End

Beispiel 4 – Color.Distance(..)

Public Sub btnDistance_Click()
 
  Dim iColor1, iColor2 As Integer
  Dim fDistance As Float
 
  iColor1 = ColorButton1.Color
  iColor2 = ColorButton2.Color
 
  fDistance = Color.Distance(iColor1, iColor2)
  Print fDistance
 
End

Mit den beiden Farben Rot (Color.RGB(255,0,0)) und Grün (Color.HSV(120,255,255)) ergibt sich ein Distance-Wert von 0,70710678118655. Ist das nicht schön! Der Autor jedenfalls ist begeistert – kann aber mit diesem Wert nichts anfangen.

Beispiel 5 – Color.Merge(..)

Public Sub btnMerge_Click()
 
    Dim iColor1, iColor2, iResultColor As Integer
    Dim fWeight As Float
 
'-- Weight is the relative weight of the first color, between 0 and 1.
    iColor1 = ColorButton1.Color
    fWeight = 0.3
    iColor2 = ColorButton2.Color
 
    iResultColor = Color.Merge(iColor1, iColor2, fWeight)
'-- iResultColor = Color.Merge(iColor1, iColor2) '-- fWeight = 0.5 (Default)
    ColorButton3.Color = iResultColor 
 
End

Beispiel 6 – Color.Gradient(..)

Public Sub btnGradient_Click()
 
    Dim iColor1, iColor2, iResultColor As Integer
    Dim fWeight As Float
 
    iColor1 = ColorButton1.Color
    iColor2 = ColorButton2.Color
'-- fWeight = 0.0 '-- Special case 1
'-- fWeight = 1.0 '-- Special case 2
    fWeight = 0.4
 
    iResultColor = Color.Gradient(iColor1, iColor2, fWeight)
'-- iResultColor = Color.Gradient(iColor1, iColor2) '-- fWeight = 0.5 (Default)
    ColorButton3.Color = iResultColor  
 
End

Beispiel 7 – Color.Blend(..)

Public Sub btnBlend_Click()
 
    Dim iSourceColor, iDestinationColor, iResultColor As Integer
 
    iSourceColor = ColorButton1.Color
    iSourceColor = Color.SetAlpha(iSourceColor, 190)
    ColorChooser1.SelectedColor = iSourceColor
 
    iDestinationColor = ColorButton2.Color
    iDestinationColor = Color.SetAlpha(iDestinationColor, 90)
    ColorChooser2.SelectedColor = iDestinationColor
 
    iResultColor = Color.Blend(iSourceColor, iDestinationColor)
    Print Color.GetAlpha(iResultColor) '-- Alternative: Print Color[iResultColor].Alpha
    ColorChooser3.SelectedColor = iResultColor
 
End